Zeta = lfuncreate(1)
lfun(Zeta,2)
lfun(Zeta,0,1)
lfun(Zeta,1)
lfun(Zeta,1+x+O(x^10))
lfunzeros(Zeta,20)
lfunlambda(Zeta,2)

G=znstar(4,1); G.clgp
Dir=lfuncreate([G,[1]]); Dir[2..5]
lfunan(Dir,30)
lfun(Dir,2)
Catalan
znconreyexp(G,[1])
lfun(Mod(3,4),2)

Dedek = lfuncreate(x^2+1); Dedek[2..5]
lfun(Dedek,2)
zeta(2)*Catalan
L=lfunmul(Zeta,Mod(3,4));
lfun(L,2)
L2=lfundiv(Dedek,1);
lfun(L2,2)

E = ellinit([0,-1,1,-10,-20]);
lfun(E,1)
ellbsd(E)
lfuncreate(E)[2..5]

nf  = nfinit(a^2-5);
phi = (1+a)/2;
E   = ellinit([1,phi+1,phi,phi,0],nf);
E.j
E.disc
N   = ellglobalred(E)[1]
tor = elltors(E) \\ Z/8Z

om = E.omega
per = om[1][1]*om[2][1];
tam = elltamagawa(E)
bsd = (per*tam) / (tor[1]^2*sqrt(abs(nf.disc)))
ellbsd(E)
L1  = lfun(E,1)

E = ellinit([0,-1,1,-10,-20]);
L=lfuntwist(E,Mod(2,5));
lfunan(E,10)
lfunan(Mod(2,5),10)
lfunan(L,10)

nf=nfinit(polcyclo(5,'a));
E2=ellinit(E[1..5],nf);
localbitprec(64); lfun(E2,2)
L2=lfuntwist(E,Mod(4,5));
lfun(E,2)*lfun(L2,2)*norm(lfun(L,2))

L=lfungenus2([x^2+x,x^3+1]);
L[2..5]
lfun(L,1)
lfunan(L,5)

bnf = bnfinit(a^2+23);
bnr = bnrinit(bnf, 1);
bnr.clgp
Hecke = lfuncreate([bnr,[1]]);
Hecke[2..5]
z=lfun(Hecke,0,1)
algdep(exp(z),3)

N = nfinit(x^6+108);
G = galoisinit(N);

[T,o] = galoischartable(G);
T~

galoisconjclasses(G)

L = lfunartin(N,G,T[,3],o);
lfuncheckfeq(L)
L[2..5]
z = lfun(L,0,1)
algdep(exp(z),3)

bnr = bnrinit(bnfinit(a^2+a+1),6);
lfunan([bnr,[1]],100)==lfunan(L,100)

E=ellinit([0,-1,1,-10,-20]);
  \\ or ellinit("11a1") if elldata is available
P=elldivpol(E,3)
Q=polresultant(P,y^2-elldivpol(E,2));
R=nfsplitting(Q)

N=nfinit(R); G=galoisinit(N);
[T,o]=galoischartable(G); T~
o

minpoly(Mod(y^3+y, polcyclo(o,y)))

L = lfunartin(N,G,T[,3],o);
L[2..5]
lfuncheckfeq(L)

dT = galoischardet(G,T[,3],o)
dL = lfunartin(N,G,dT,o);
dL[2..5]

mf=mfinit([3267,1,-3],1);
M=mfeigenbasis(mf);
C=mfcoefs(M[3],100);
mfembed(M[3],C)[2][2..-1]==lfunan(L,100)

S = lfunan(L,1000); SE = lfunan(E,1000);
Smod3 = round(real(S))+round(imag(S)/sqrt(2));
[(Smod3[i]-SE[i])%3|i<-[1..#Smod3],gcd(i,33)==1]

bnf6=bnfinit(a^6-3*a^5+6*a^4+4*a^3+6*a^2-3*a+1);
bnr6=bnrinit(bnf6,1);
L1=lfuncreate([bnr6,[1]]);
L1[2..5]
bnf4=bnfinit(a^4-a^3+3*a^2+a-1);
pr4 = idealprimedec(bnf4,3)[1];
bnr4=bnrinit(bnf4,[pr4,[0,1]]);
L2=lfuncreate([bnr4,[1]]);
L2[2..5]

LL = lfundiv(L1,L2); LL[2..5]
round(lfunan(L,1000)-lfunan(LL,1000),&e)
e