Re: Question related to an unramified cubic extension polynomial

[Bill Allombert <Bill.Allombert@math.u-bordeaux.fr>]

On Wed, Mar 30, 2022 at 09:14:11PM +0200, Eleni Agathocleous wrote:
> Hello
> 
> I have a question regarding the computation of the unramified cubic
> extensions of the real quadratic field K_D with discriminant
> D=4*(m)^3-27*(n)^2= 48035713, for m=229, n=3. I wrote the discriminant
> like this since in cases where the class number is divisible by 3 the
> discriminants can be written in this form, for finitely many pairs
> (m,n), and the polynomials f=x^3-m*x+n define unramified cubic
> extensions (when gcd(2m,3n)=1).
> 
> The ideal class group CL(K_D) of K_D has 3-rank 2 and is of the form
> (C6)x(C6). I computed the four polynomials giving me the 4=(3^2-1)/2
> unramified cubic extensions but only one of the polynomials has
> poldisc equal to the discriminant of K_D, namely the polynomial f. The
> following is a classical result of Hasse:
> "For K a quadratic number field of discriminant D, and r the 3-rank of
> the ideal class group of K, the number of non-conjugate cubic fields
> of discriminant D is m = (3r − 1)/2."
> 
> My question is two-fold: In this case for this D= 48035713, is it
> because of computational limitations that PARI gives me only one
> polynomial with discriminant D (namely the f=x^3-mx+n)? 

Hello Eleni,
Could you clarify which command you issued that gives you a single
polynomial ?

You can proceed as follow 

? bnf=bnfinit(quadpoly(48035713,'a),1);
? bnrclassfield(bnf,3)
%2 = [x^3-5853*x-156580,x^3+(3891134060370*a-13486242851888223)*x+(245953599375323953710*a-852448134659276677806065)]
But this gives you polynomials defined over K_D.

If you want all absolute polynomials, the simplest is 
? R = nfsubfields(bnrclassfield(bnf,3,2),3,1);

Now you should reduce them:
? Rmin = Set(apply(polredabs,R))
%49 = [x^3-x^2-1662*x-5633,x^3-229*x-3,x^3-x^2-1858*x+3719,x^3-x^2-650*x+6016]
So you get 4 disctincts polynomials as expected.

? disc=apply(poldisc,Rmin)
%50 = [17340892393,48035713,25410892177,192142852]
Only the second one has exactly the right discriminant.

? apply(nfdisc,Rmin)
%51 = [48035713,48035713,48035713,48035713]
but they all have the right field discriminant.

Given a field, it is difficult and often impossible to find a polynomial
with the same discriminant as the field. In this instance I do not think
it is possible due to ...

> Finding another polynomial of discriminant D would give a specific
> elliptic curve, namely the curve E:y^2=x^3-27*16*D, a second point
> (the first one is the point P=[12m,108n]) which would be independent
> form P and this would result to the curve having rank>=2 instead of
> rank=1 which is what I get now.

... alas, the rank of this curve is 1:

? ellrank(E)
%47 = [1,1,0,[[2748,324]]]

so you will not find new independent points.

If you want a D for which this method gives more points, try D=-3321607

Thanks for your question!
Bill