Learning with GP: Verification of identities - Romik sequence

[Jacques Gélinas <jacquesg00@hotmail.com>]

The finite expression DT3 below has been found in [2]
for derivatives at x=1 of the third Jacobi theta constant,
   theta3(x) := sum(n=-oo,oo,exp(-n^2*Pi*x))
This involves  a new "Romik sequence" of integers dk
defined via the infinite series dh(k) below [2,3].

0. In order to verify identities for this sequence
we use comparison routines from [1] (verif.gp).

\\-------------------------------------------- Start cut

eqr(x,y) = if(x==y,1,exponent(if(!x,y,1-y/x))/exponent(0.));
fleq(x,y,r=7/8) = if(x==y, 1, r <= \
                    eqr(0,normlp(x-y)/normlp(x+y)));
IS(e,msg="") = print(if(e,"Pass: ","Fail: "),msg);
ISF(x,y,msg="",r=7/8) = IS( fleq(x,y,r),msg);
ISN(f,g,msg="",r=7/8,N=12) = IS( N == 
             sum(n=1,N, fleq(f(n),g(n),r)), msg);

/*1. The derivatives of theta3(x) at x=1 are equal to
a rational polynomial in Pi and in T1 := theta(1)
which can be computed in many different ways by GP.*/

T1 = Pi^(1/4) / gamma(3/4);  \\ 1.0864348... oeis.org/A175573
ISF( T1, 1/sqrt(2*Pi)*gamma(1/4)/Pi^(1/4), "T1 gamma(1/4)" );
ISF( T1, 1+2*sumpos(n=1,exp(-n^2*Pi)), "T1 definition");
ISF( T1, 4/(1-2^(-1/4))*sumpos(n=1,exp(-(2*n-1)^2*Pi)),\
    "T1 Whittaker-Watson, Modern Analysis p. 533" );

\\ L-functions (Bill Allombert)
tzeta(x) = 1 + lfuntheta(1,sqrt(x));  \\ associated to zeta
ISF( T1, tzeta(1), "T1=1+lfuntheta(1,sqrt(1))" );
Dtheta3(n=0,x=1) = lfuntheta(lfunqf(Mat(1)),x,n)/2 + (!n);
ISF( T1, Dtheta3(0), "T1=Dtheta3(0,1) via lfuntheta(lfunqf)" );

\\ modular forms with q=exp(2*I*Pi*z) (Bill Allombert)
mf = mfinit(Tm=mfTheta());
ISF( T1, mfeval(mf,Tm,I/2), "T1 via mfTheta" );
[mf,F] = mffromqf(Mat(2));
ISF( T1, mfeval(mf,F,I/2), "T1 via mffromqf" );

/*2. Each Romik integer can be computed by summing an
infinite series of weighted Hermite polynomial values.
At least 450D/25 terms are needed to verify the
Zeilberger value [3]   dk(100) = -4.7885...33551E336,
and 1000D/35 terms for dk(200) = -1.2713...63551E792.
We verify the first nine integers and also twice a
(simplified) formula for the first twelve derivatives.*/

B = 2 * Pi^2 * T1^8;         \\ 4*\Omega in [2]=38.31...
dk(k) = round(dh(k)/T1/B^k); \\ [2, Proposition 10]
dh(k) = my(z, pk=y->substpol(polhermite(4*k),x^2,2*y) );\
        pk(0) + 2*suminf(n=1,z=n^2*Pi; exp(-z)*pk(z) );
IS( [1,1,-1,51,849,-26199,1341999,82018251,18703396449] ==
    [dk(k)|k<-[0..8]], "Romik sequence d[0..8]" );

               \\ DT3(n) = theta3^(n)(1) [2, Theorem 1]
DT3(n) = (2*n)!/(-8)^n*sum(k=0,n/2, dh(k)/(n-2*k)!/(4*k)!);
ISN( DT3, n->derivnum(x=1,tzeta(x),n), "DT3 vs derivnum" );
ISN( DT3, Dtheta3, "DT3 vs lfuntheta(lfunqf)" );

/*3. The functional equation theta3(1/x)=sqrt(x)*theta3(x),
when differentiated and evaluated at x=1, yields a sequence
of identities (such as -2*theta3'(1) = theta3(1)/2) that
we use to verify our version DT3 of the Romik formula.*/

                       \\ Coffey identities [4]
ISF( -2*DT3(1), T1/2, "-2*theta3'(1) = theta3(1)/2" );
ff(n) = prod(j=1,n,2*j-1);  \\ !!=double factorial
ISN({ n-> if(n==1,0,(1-(-1)^n)*DT3(n) - ff(n-1)*T1/(-2)^n),
      n-> sum(j=1,n-1,binomial(n,j)*DT3(j)*
          ((-1)^n*(n-1)!/(j-1)! + ff(n-j-1)/(-2)^(n-j))),
      "Coffey identities for theta3^(n)(1)");}

\\-------------------------------------------- End paste

------------------------------ Features used
!,Pi,my,prod,sum,sumpos,suminf,binomial,gamma,
exponent,normlp,round,derivnum,exp,substpol,
sqrt,polhermite,(anonymous closure),[f(n)|n<-[...]],
lfuntheta,lfunqf,mfinit,mfeval,mfTheta,mffromqf

------------------------------ References
[1] Learning with GP: Verification of identities 2019-04-08
    pari.math.u-bordeaux.fr/archives/pari-users-1904/msg00008.html
[2] Romik 2018 The Taylor coefficients of the Jacobi theta constant theta_3,
    arxiv.org/abs/1807.06130, to be published in The Ramanujan Journal.
[3] Sequence related to the Jacobi theta_3 constant, oeis.org/A317651
    Maple code from Doron Zeilberger and first 200 integers available at
    sites.math.rutgers.edu/~zeilberg/mamarim/mamarimhtml/Theta3RomikUM.html
[4] Coffey 2002 A set of identities for a theta function at a unit argument,
    Physics Letters A, 300:367-369.
[5] Tutorials: pari.math.u-bordeaux.fr/pub/pari/manuals/2.12.0/tutorial.pdf
    pari.math.u-bordeaux.fr/pub/pari/manuals/2.12.0/tutorial-mf.pdf
[6] Reference cards: http://pari.math.u-bordeaux.fr/pub/pari/manuals/2.12.0/refcard.pdf
    pari.math.u-bordeaux.fr/pub/pari/manuals/2.11.1/refcard-mf.pdf

Jacques Gélinas